店舗の商品データで簡易的に商品を登録 β版【Shopify】 ID:62730

Shopifyから出力した商品データを本システムに取り込み、商品管理データを簡易的に登録する手順です。
在庫連携・受注処理機能を利用する際に必要な最低限の項目のみ登録します。

商品登録データは、Googleスプレッドシート上で関数を活用して作成します。

ご利用時の注意

・Excelでは本機能をご利用いただけません。
・スプレッドシートの操作方法については、本マニュアル記載内容を超える部分のご案内はできません。
・本手順は参考情報としてご提供しており、サポート対象外です。
・Shopify側の仕様変更には追従しておりません。

1．事前の確認事項

■商品コードの統一
本機能のご利用前に、必ず商品コードの統一を行ってください。
商品コードの統一ルールは下記をご参照ください。
※SKUが未登録の商品はスキップされます。事前にSKUが登録されているかご確認ください。

商品コードのルール

■新規登録時の必須項目
商品情報、およびページ情報を新規登録する際の必須項目は、以下のとおりです。
商品コード(syohin_code)・仕入先コード(sire_code)・商品名(syohin_name)・原価(genka_tnk)・売価(baika_tnk)

■セット商品・コピーページ商品を取り扱っている場合
セット商品・コピーページ商品は、セット商品管理に登録する必要があります。
本機能では、セット商品管理への登録ができないため、別途セット商品管理への登録を行ってください。

2．操作手順

2-1．Shopify管理画面にてファイルをダウンロード

【Shopify管理画面】

[商品管理]をクリック

[エクスポート]をクリック

[商品をエクスポートする]をクリック

2-2．CSVファイルを編集する

【Googleスプレッドシート画面】

新しくGoogleスプレッドシートを作成し、
[ファイル]より[インポート]をクリック

インポート場所を[選択したセルを先頭にデータを置換する]に変更
[データをインポート]をクリック

正しくインポートが行われると下記のようになります。

以下の関数をコピーする

={
  "syohin_name", "syohin_code", "baika_tnk", "sire_code", "genka_tnk";
  ARRAYFORMULA(
    LET(
      h, 'シート1'!1:1,
      d, 'シート1'!2:20000,
      t_col, MATCH("Title", h, 0),
      o1_col, MATCH("Option1 Value", h, 0),
      o2_col, MATCH("Option2 Value", h, 0),
      s_col, MATCH("Variant SKU", h, 0),
      p_col, MATCH("Variant Price", h, 0),
      c_col, MATCH("Cost per item", h, 0),
      sku, INDEX(d,, s_col),
      sku_check, COUNTA(sku),
      IF(sku_check = 0,
        {"SKUがすべて空白です、商品管理コードに値を入力してからお試しください", "", "", "", ""},
        LET(
          raw_t, INDEX(d,, t_col),
          f_title, SCAN("", raw_t, LAMBDA(p, c, IF(c="", p, c))),
          FILTER(
            {
              f_title & " " & INDEX(d,, o1_col) & " " & INDEX(d,, o2_col),
              sku,
              INDEX(d,, p_col),
              IF(NOT(sku=""), "9999", ""),
              IF(INDEX(d,, c_col)="", 0, INDEX(d,, c_col))
            },
            NOT(sku = "")
          )
        )
      )
    )
  )
}

↓
スプレッドシートに新しいシートを追加
↓
新しいシートのA1セルを選択し、fx欄にコピーした関数を貼り付け

正しく変換が行われると下記のようになります。